FRITZ! Box Fon WLAN 7270 Version 54.04.93-11181 (Gaming-Labor)

PROGRAM WakeOnLAN;

//
// Small tool written by MR - 10/2007
//

{$APPTYPE CONSOLE}

USES SysUtils,
     IdUDPClient;

VAR UDPClient   : TIdUDPClient;
    I,J         : INTEGER;
    S,SX        : STRING;
    MagicPacket : ARRAY[1..16*6+6] OF BYTE;

BEGIN
  //
  // Analyse command parameters.
  //
  IF ParamCount <> 1 THEN
    WriteLn('Usage: WakeOnLAN <MAC address>')
  ELSE BEGIN
    S := ParamStr(1);
    //
    // Create a 6 Byte true hex string (only digits).
    //
    FOR I:=Length(S) DOWNTO 1 DO BEGIN
      CASE S[i] OF
        '0'..'9',
        'A'..'F',
        'a'..'f' : { o.k. };
        ELSE
          Delete(S,I,1);
      END;  { CASE }
    END;  { FOR }
    IF Length(S) <> 12 THEN
      WriteLn('Bad MAC address!') // uups.
    ELSE BEGIN
      //
      // Create "magic packet".
      // 6x $FF
      // 16x MAC address á 6 Byte (12 hex chars).
      //
      FOR I:=1 TO 6 DO
        MagicPacket[i] := $FF;
      FOR I:=0 TO 5 DO BEGIN
        SX := '$'+Copy(S,1,2);
        Delete(S,1,2);
        MagicPacket[I+7] := StrToInt(SX);
        FOR J:=1 TO 15 DO
          MagicPacket[6*J+I+7] := MagicPacket[I+7];
      END;  { FOR }
      //
      // Send the packet with UDP (stateless protocol).
      //
      UDPClient := TIdUDPClient.Create(NIL);
      UDPClient.BroadcastEnabled := TRUE;  // VERY important!
      TRY
        UDPClient.Host := '255.255.255.255';
        UDPClient.Port := 80;
        UDPClient.SendBuffer(MagicPacket,SizeOf(MagicPacket));
      EXCEPT
        ON E : Exception DO
          WriteLn(E.Message);
      END;
      UDPClient.Free;
    END;  { ELSE }
  END;  { ELSE }
END.